Contenu

# Instruction Property

Une propriété, également appelée champ ou attribut, caractérise un objet ou une information donné. Les propriétés peuvent être utilisées pour contrôler l'accès aux données. Il est courant d'inclure des instructions pour définir ou lire l'heure des propriétés. Le code peut varier d'une simple affectation à des routines complexes dépendant du contexte. L'utilisation des accesseurs Get, Let ou Set renforce la cohérence des propriétés lorsque cela est nécessaire.

Cette instruction nécessite que Option Compatible soit placée avant le code du programme exécutable dans un module.

### Syntaxe :

             [Private | Public] Property Get name[char | As typename]
             End Property

             [Private | Public] Property [Let | Set] name[char] [([Optional [ByRef | ByVal]]value[char | As typename])] [As typename]
             End Property

### Paramètres :

name: le nom de la propriété

argument: valeur à transmettre à la routine de définition de Property.

Les définitions de Property utilisent souvent un seul argument. Les arguments multiples sont également acceptés.

##### fragment d'argument

          {[Optional [ByRef|ByVal]]|ParamArray} argument {{As typename|char}[ = expression]|[()]As Variant}

##### Paramètres

Optional : l'argument n'est pas obligatoire.

ByRef: l'argument est passé par référence. ByRef est par défaut.

ByVal: l'argument est passé par valeur. Sa valeur peut être modifiée par la routine appelée.

char: caractère de déclaration Type

typename: nom du type de données primitif. Les types définis par la bibliothèque ou le module peuvent également être spécifiés.

=expression: spécifiez une valeur par défaut pour l'argument, correspondant à son type déclaré. Optional est nécessaire pour chaque argument spécifiant une valeur par défaut.

ParamArray: utilisez ParamArray quand le nombre de paramètres est indéterminé. Un scénario typique est celui d'une fonction définie par l'utilisateur Calc. L'utilisation de ParamArray doit être limitée au dernier argument d'une routine.

L'utilisation de ParamArray ou = expression nécessite que Option Compatible soit placé avant le code du programme exécutable dans un module.

Lors de l'utilisation de Option VBASupport 1, les arguments Optional sans valeur par défaut (=expression) sont initialisés en fonction de leur type de données, sauf utilisation de Variant.

##### fragment typename

          {Boolean|Byte|Currency|Date|Double|Integer|Long|Object|Single|String|Variant}

##### fragment char

          { % | & | ! | # | $ | @ }

## Exemples

          Option Compatible
          Sub Main
              ProductName = "Office"
              Print ProductName ' affiche "LibreOffice"
          End Sub

          Private _office As String
          Property Get ProductName As String
              ProductName = _office
          End Property
          Property Let ProductName(value As String)
              _office = "Libre"& value
          End Property

En l'absence de Property Let ou Property Set, Property Get permet de définir les informations protégées, qui ne peuvent pas être accidentellement modifiées par un module étranger :

          Option Compatible
          Public Property Get PathDelimiter As String ' variable en lecture seule
              Static this As String
              If this = "" Then : Select Case GetGuiType()
                  Case 1 : this = ";" ' Windows
                  Case 4 : this = ":" ' Linux ou macOS
                  Case Else : Error 423 ' Propriété ou méthode non définie : PathDelimiter
              End Select : End If
              PathDelimiter = this
          End Property ' PathDelimiter en lecture seule

          Sub Main
              PathDelimiter = "a sentence" ' ne fait rien
          End Sub

Utilisez Let ou Set lors de la gestion de services UNO ou objets de classe :

          Option Compatible
          Sub Main
              'Set anObject = CreateUnoService( "com.sun.star.frame.Desktop" )
              anObject = CreateUnoService( "com.sun.star.frame.Desktop" )
              Print anObject.SupportedServiceNames(0) ' displays "com.sun.star.frame.Frame"
          End Sub

          Property Get anObject As Object
              Set anObject = _obj
          End Property

          Private _obj As Object

          'Property Set anObject(value As Object)
              'Set _obj = value.CurrentFrame
          'End Property
          Property Let anObject(value As Object)
              Set _obj = value.CurrentFrame
          End Property

Rubriques connexes

Bases des sous-routines

Utilisation de procédures, fonctions et propriétés

Instruction Function

Instruction Sub

Instructions End Exit

Instruction Option ClassModule

Instruction Option Compatible

Aidez-nous !